相同表名如何合并到一个文件中?（怎么把一个表格中相同的名称合并）

虽然已是2020，但是离春节还有些时日！直到年底，办公一族还是有一段时间忙碌的，表哥表姐们加油吧！
我们实战第三期，说一下如何把相同表名的工作表合并到一个文件中，方便查找后续处理，希望对大家年终汇总有所帮助！
一图胜千言：GIF动画演示效果

简述：以上按给定路径和表名的所有相同表名合并到一起，细节如下详述。
素材：4张-包含分组的表的文件，以分组表为合并对象

素材说明：F2单元格中的月份作为合并后的表名

代码截图如下：

源码（复制粘贴可用）：

Option Explicit

'功能：复制不同工作薄中相同表名工作表到当前表中
'作者：Excel办公实战-小易
'日期：2020-1-6
'------------------------------------------------------------
Sub CombineShtByName()
    '-变量申明
    Dim fileName As String, wb As Workbook, sShtName As String
    Dim sTargetShtName  As String, sPath  As String
    Dim resCount As Long, ShtCount As Long
    
    With ThisWorkbook.Sheets("配置")
        '需要复制的表名-自行修改配置
         sPath = .Range("B1").Value & "\"
        '需要合并的文件所在的文件夹路径
        sTargetShtName = .Range("B2").Value
    End With
    
    '关闭屏幕刷新，提速
    Application.ScreenUpdating = False
    
    'Dir获取Excel文件名
    fileName = Dir(sPath & "*.xl*")
    '循环处理每一个
    Do While Len(fileName) > 0
        '打开对应的工作表
        Set wb = Workbooks.Open(sPath & fileName, False, True)
        
        '判断是否存在对应要复制的表，存在方可操作[自定义函数]
        If bExistsShtByName(sTargetShtName, wb.Name) Then
            '统计满足条件的个数
            resCount = resCount + 1
            '复制到当前工作薄所有工作表的最后
            ShtCount = ThisWorkbook.Worksheets.Count
            wb.Sheets(sTargetShtName).Copy after:=ThisWorkbook.Worksheets(ShtCount)
            '已要复制的工作表的F2单元格内容作为新的表名，可自行配置
            sShtName = wb.Sheets(sTargetShtName).[F2]
            '关闭不保存
            wb.Close 0
            '重命名复制过来的表
            ActiveSheet.Name = sShtName
        End If
        '下一个需要复制的文件
        fileName = Dir
    Loop
    
     '结束开启
    Application.ScreenUpdating = True
    MsgBox "合并完成，共合并" & resCount & "个", vbInformation, "提示"
End Sub

'作者:小易
'日期:2019-11-28
'功能:判断工作表是否存在
'参数：
'   sShtName        :工作表名称
'   sParentWbName   :工作簿名称
'------------------------------------------------------------------
Function bExistsShtByName(sShtName As String, Optional sParentWbName As Variant)
    Dim wbName As String
    If IsMissing(sParentWbName) Then
        wbName = ThisWorkbook.Name
    Else
        If InStr(sParentWbName, ".") = 0 Then
            wbName = sParentWbName & ".xlsx"
        Else
            wbName = sParentWbName
        End If
    End If
    bExistsShtByName = Not (TypeName(Application.Evaluate( _
            "'[" & wbName & "]" & sShtName & "'!A1")) = "Error")
End Function

小结：按表名合并，也算是一种常见的汇总问题，整体核心至少有复制的两三句，难度较小，是否新手练习，本文代码可复制简单修改，用于实际工作中

欢迎关注Excel办公实战，更多精彩不断奉送